feat: implement target configuration system for issue #1176

Add comprehensive target configuration parsing and inheritance system:

- Create internal/targets package with config structures
- Support JSON configuration loading with inheritance resolution
- Implement multi-level inheritance (e.g., rp2040 → cortex-m0plus → cortex-m)
- Add 206 target configurations from TinyGo for embedded platforms
- Support core fields: name, llvm-target, cpu, features, build-tags, goos, goarch, cflags, ldflags
- Provide high-level resolver interface for target lookup
- Include comprehensive unit tests with 100% target parsing coverage

This foundation enables future -target parameter support for cross-compilation
to diverse embedded platforms beyond current GOOS/GOARCH limitations.

🤖 Generated with [Claude Code](https://claude.ai/code)

Co-Authored-By: Claude <noreply@anthropic.com>

targets/maixbit.ld

@@ -0,0 +1,65 @@
+
+MEMORY
+{
+    RAM (xrw) : ORIGIN = 0x80000000, LENGTH = 6M
+}
+
+_stack_size = 2K;
+
+SECTIONS
+{
+    .text :
+    {
+        . = ALIGN(16);
+        KEEP(*(.init))
+        . = ALIGN(16);
+        *(.text.handleInterruptASM)
+        *(.text)
+        *(.text.*)
+        *(.rodata)
+        *(.rodata.*)
+        . = ALIGN(16);
+    } >RAM
+
+
+    /* Start address (in flash) of .data, used by startup code. */
+    _sidata = LOADADDR(.data);
+
+    /* Globals with initial value */
+    .data :
+    {
+        . = ALIGN(16);
+        /* see https://gnu-mcu-eclipse.github.io/arch/riscv/programmer/#the-gp-global-pointer-register */
+        PROVIDE( __global_pointer$ = . + (4K / 2) );
+        _sdata = .;        /* used by startup code */
+        *(.sdata)
+        *(.data .data.*)
+        . = ALIGN(16);
+        _edata = .;        /* used by startup code */
+    } >RAM
+
+    /* Zero-initialized globals  */
+    .bss :
+    {
+        . = ALIGN(16);
+        _sbss = .;         /* used by startup code */
+        *(.sbss)
+        *(.bss .bss.*)
+        *(COMMON)
+        . = ALIGN(16);
+        _ebss = .;         /* used by startup code */
+    } >RAM
+
+    /DISCARD/ :
+    {
+        *(.eh_frame)       /* causes 'no memory region specified' error in lld */
+    }
+}
+
+PROVIDE(_stack_top = ORIGIN(RAM) + LENGTH(RAM));
+
+/* For the memory allocator. */
+_heap_start = _ebss;
+_heap_end = ORIGIN(RAM) + LENGTH(RAM) - _stack_size;
+_globals_start = _sdata;
+_globals_end = _ebss;